Main.v

   1 /*
   2  * MandelFPGA
   3  * by Joshua Wise and Chris Lu
   4  *
   5  * An implementation of a pipelined algorithm to calculate the Mandelbrot set
   6  * in real time on an FPGA.
   7  */
   8
   9 `define XRES 640
  10 `define YRES 480
  11 `define WHIRRRRR 27
  12
  13 module SyncGen(
  14         input pixclk,
  15         output reg vs, hs,
  16         output reg [11:0] xout = `WHIRRRRR, yout = 0,
  17         output wire [11:0] xoutreal, youtreal,
  18         output reg border);
  19
  20         reg [11:0] x = 0, y = 0;        // Used for generating border and timing.
  21         assign xoutreal = x;
  22         assign youtreal = y;
  23
  24         parameter XFPORCH = 16;
  25         parameter XSYNC = 96;
  26         parameter XBPORCH = 48;
  27
  28         parameter YFPORCH = 10;
  29         parameter YSYNC = 2;
  30         parameter YBPORCH = 29;
  31
  32         always @(posedge pixclk)
  33         begin
  34                 if (x >= (`XRES + XFPORCH + XSYNC + XBPORCH))
  35                 begin
  36                         if (y >= (`YRES + YFPORCH + YSYNC + YBPORCH))
  37                                 y <= 0;
  38                         else
  39                                 y <= y + 1;
  40                         x <= 0;
  41                 end else
  42                         x <= x + 1;
  43
  44                 if (xout >= (`XRES + XFPORCH + XSYNC + XBPORCH))
  45                 begin
  46                         if (yout >= (`YRES + YFPORCH + YSYNC + YBPORCH))
  47                                 yout <= 0;
  48                         else
  49                                 yout <= yout + 1;
  50                         xout <= 0;
  51                 end else
  52                         xout <= xout + 1;
  53                 hs <= (x >= (`XRES + XFPORCH)) && (x < (`XRES + XFPORCH + XSYNC));
  54                 vs <= (y >= (`YRES + YFPORCH)) && (y < (`YRES + YFPORCH + YSYNC));
  55                 border <= (x > `XRES) || (y > `YRES);
  56         end
  57 endmodule
  58
  59 // bits: 1.12
  60
  61 module NaiveMultiplier(
  62         input clk,
  63         input [12:0] x, y,
  64         input xsign, ysign,
  65         output reg [12:0] out,
  66         output reg sign,
  67         output reg ovf);
  68
  69         always @(posedge clk)
  70         begin
  71                 {ovf,out} <=
  72                         (((y[12] ? (x     ) : 0)  +
  73                           (y[11] ? (x >> 1) : 0)  +
  74                           (y[10] ? (x >> 2) : 0)) +
  75                         (((y[9]  ? (x >> 3) : 0)  +
  76                           (y[8]  ? (x >> 4) : 0))+
  77                     ((y[7]  ? (x >> 5) : 0)  +
  78                           (y[6]  ? (x >> 6) : 0))))+
  79
  80                         (((y[5]  ? (x >> 7) : 0)  +
  81                           (y[4]  ? (x >> 8) : 0)+
  82                           (y[3]  ? (x >> 9) : 0)) +
  83                          ((y[2]  ? (x >> 10): 0) +
  84                           (y[1]  ? (x >> 11): 0)  +
  85                           (y[0]  ? (x >> 12): 0)));
  86                 sign <= xsign ^ ysign;
  87         end
  88
  89 endmodule
  90
  91 module Multiplier(
  92         input clk,
  93         input [12:0] x, y,
  94         input xsign, ysign,
  95         output wire [12:0] out,
  96         output wire sign,
  97         output wire overflow);
  98
  99         NaiveMultiplier nm(clk, x, y, xsign, ysign, out, sign, overflow);
 100
 101 endmodule
 102
 103 // Yuq.
 104 module MandelUnit(
 105         input clk,
 106         input [12:0] x, y,
 107         input xsign, ysign,
 108         input [14:0] r, i,
 109         input rsign, isign,
 110         input [7:0] ibail, icuriter,
 111         output reg [12:0] xout, yout,
 112         output reg xsout, ysout,
 113         output reg [14:0] rout, iout,
 114         output reg rsout, isout,
 115         output reg [7:0] obail, ocuriter);
 116
 117         wire [14:0] r2, i2, ri, diff;
 118         wire [15:0] twocdiff;
 119         wire r2sign, i2sign, risign, dsign;
 120         wire [15:0] bigsum;
 121         wire bigsum_ovf, rin_ovf, iin_ovf, throwaway;
 122
 123         reg [12:0] xd, yd;
 124         reg ineedbaild;
 125         reg xsd, ysd;
 126         reg [7:0] ibaild, curiterd;
 127
 128         assign ri[0] = 0;
 129
 130         Multiplier r2m(clk, r[12:0], r[12:0], rsign, rsign, r2[12:0], r2sign, r2[13]);
 131         Multiplier i2m(clk, i[12:0], i[12:0], isign, isign, i2[12:0], i2sign, i2[13]);
 132         Multiplier rim(clk, r[12:0], i[12:0], rsign, isign, ri[13:1], risign, ri[14]);
 133
 134         assign bigsum = r2 + i2;
 135         assign bigsum_ovf = bigsum[15] | bigsum[14];
 136
 137         assign twocdiff = r2 - i2;
 138         assign diff = twocdiff[15] ? -twocdiff : twocdiff;
 139         assign dsign = twocdiff[15];
 140
 141         wire [15:0] twocrout = xd - diff;
 142         wire [15:0] twociout = yd - ri;
 143
 144         always @ (posedge clk)
 145         begin
 146                 xd <= x;
 147                 yd <= y;
 148                 xsd <= xsign;
 149                 ysd <= ysign;
 150                 xout <= xd;
 151                 yout <= yd;
 152                 xsout <= xsd;
 153                 ysout <= ysd;
 154                 ibaild <= ibail;
 155                 curiterd <= icuriter;
 156                 ineedbaild <= r[13] | r[14] | i[13] | i[14];
 157
 158                 // r^2 - i^2 + x
 159                 if (xsd ^ dsign) begin
 160                         if (twocrout[15]) begin // diff > xd
 161                                 rout <= -twocrout;
 162                                 rsout <= dsign;
 163                         end else begin
 164                                 rout <= twocrout;
 165                                 rsout <= xsd;
 166                         end
 167                 end else begin
 168                         rout <= diff + xd;
 169                         rsout <= xsd;   // xsd == dsign
 170                 end
 171
 172                 // 2 * r * i + y
 173                 if (ysd ^ risign) begin
 174                         if (twociout[15]) begin // ri > yd
 175                                 iout <= -twociout;
 176                                 isout <= risign;
 177                         end else begin
 178                                 iout <= twociout;
 179                                 isout <= ysd;
 180                         end
 181                 end else begin
 182                         iout <= ri + yd;
 183                         isout <= ysd;
 184                 end
 185
 186                 // If we haven't bailed out, and we meet any of the bailout conditions,
 187                 // bail out now.  Otherwise, leave the bailout at whatever it was before.
 188                 if ((ibaild == 255) && (bigsum_ovf | ineedbaild))
 189                         obail <= curiterd;
 190                 else
 191                         obail <= ibaild;
 192                 ocuriter <= curiterd + 8'b1;
 193         end
 194
 195 endmodule
 196
 197 module Mandelbrot(
 198         input mclk,
 199         input pixclk,
 200         input [11:0] x, y,
 201         input [13:0] xofs, yofs,
 202         input [7:0] colorofs,
 203         input [2:0] scale,
 204         output reg [2:0] red, green, output reg [1:0] blue);
 205
 206 `define MAXOUTN 11
 207
 208         wire [12:0] rx, ry;
 209         wire [13:0] nx, ny;
 210         wire rxsign, rysign;
 211
 212         assign nx = x + xofs;
 213         assign ny = y + yofs;
 214         assign rx = (nx[13] ? -nx[12:0] : nx[12:0]) << scale;
 215         assign rxsign = nx[13];
 216         assign ry = (ny[13] ? -ny[12:0] : ny[12:0]) << scale;
 217         assign rysign = ny[13];
 218
 219         wire [14:0] mr[`MAXOUTN:0], mi[`MAXOUTN:0];
 220         wire mrs[`MAXOUTN:0], mis[`MAXOUTN:0];
 221         wire [7:0] mb[`MAXOUTN:0];
 222         wire [12:0] xprop[`MAXOUTN:0], yprop[`MAXOUTN:0];
 223         wire xsprop[`MAXOUTN:0], ysprop[`MAXOUTN:0];
 224         wire [7:0] curiter[`MAXOUTN:0];
 225
 226         reg [14:0] initx, inity, initr, initi;
 227         reg [7:0] initci, initb;
 228         reg initxs, initys, initrs, initis;
 229
 230         // Values after the number of iterations denoted by the subscript.
 231         reg [14:0] stagex [2:1], stagey [2:1], stager [2:1], stagei [2:1];
 232         reg [7:0] stageci [2:1], stageb [2:1];
 233         reg stagexs [2:1], stageys [2:1], stagers [2:1], stageis [2:1];
 234
 235         reg [2:0] state = 3'b001;       // One-hot encoded state.
 236
 237         // States are advanced one from what they should be, so that they'll
 238         // get there on the _next_ mclk.
 239         always @(posedge mclk)
 240         begin
 241                 initx <= (state[2]) ? rx :
 242                     (state[0]) ? stagex[1] :
 243                     (state[1]) ? stagex[2] : 0;
 244                 inity <= (state[2]) ? ry :
 245                        (state[0]) ? stagey[1] :
 246                        (state[1]) ? stagey[2] : 0;
 247                 initr <= (state[2]) ? rx :
 248                        (state[0]) ? stager[1] :
 249                        (state[1]) ? stager[2] : 0;
 250                 initi <= (state[2]) ? ry :
 251                        (state[0]) ? stagei[1] :
 252                        (state[1]) ? stagei[2] : 0;
 253                 initxs <= (state[2]) ? rxsign :
 254                         (state[0]) ? stagexs[1] :
 255                         (state[1]) ? stagexs[2] : 0;
 256                 initys <= (state[2]) ? rysign :
 257                         (state[0]) ? stageys[1] :
 258                         (state[1]) ? stageys[2] : 0;
 259                 initrs <= (state[2]) ? rxsign :
 260                         (state[0]) ? stagers[1] :
 261                         (state[1]) ? stagers[2] : 0;
 262                 initis <= (state[2]) ? rysign :
 263                         (state[0]) ? stageis[1] :
 264                         (state[1]) ? stageis[2] : 0;
 265                 initb <= (state[2]) ? 8'b11111111 :
 266                        (state[0]) ? stageb[1] :
 267                        (state[1]) ? stageb[2] : 0;
 268                 initci <= (state[2]) ? 8'b00000000 :
 269                         (state[0]) ? stageci[1] :
 270                         (state[1]) ? stageci[2] : 0;
 271         end
 272
 273         reg [7:0] out;
 274
 275         // We detect when the state should be poked by a high negedge followed
 276         // by a high posedge -- if that happens, then we're guaranteed that the
 277         // state following the current state will be 3'b100.
 278         reg lastneg;
 279         always @(negedge mclk)
 280                 lastneg <= pixclk;
 281
 282         always @(posedge mclk)
 283         begin
 284                 if (lastneg && pixclk)  // If a pixclk has happened, the state should be reset.
 285                         state <= 3'b100;
 286                 else                                            // Otherwise, just poke it forward.
 287                         case(state)
 288                         3'b001: state <= 3'b010;
 289                         3'b010: state <= 3'b100;
 290                         3'b100: state <= 3'b001;
 291                         endcase
 292
 293                 // Data output handling
 294                 if (state[0]) begin
 295                         {red, green, blue} <= {out[0],out[3],out[6],out[1],out[4],out[7],out[2],out[5]};
 296                 end
 297                 if (state[1]) begin
 298                         out <= ~mb[`MAXOUTN] + colorofs;
 299                 end
 300
 301                 if (state[0]) begin             // PnR0 in, PnR2 out
 302                         stagex[2] <= xprop[`MAXOUTN];
 303                         stagey[2] <= yprop[`MAXOUTN];
 304                         stager[2] <= mr[`MAXOUTN];
 305                         stagei[2] <= mi[`MAXOUTN];
 306                         stagexs[2] <= xsprop[`MAXOUTN];
 307                         stageys[2] <= ysprop[`MAXOUTN];
 308                         stagers[2] <= mrs[`MAXOUTN];
 309                         stageis[2] <= mis[`MAXOUTN];
 310                         stageb[2] <= mb[`MAXOUTN];
 311                         stageci[2] <= curiter[`MAXOUTN];
 312                 end
 313
 314                 if (state[2]) begin     // PnR2 in, PnR1 out
 315                         stagex[1] <= xprop[`MAXOUTN];
 316                         stagey[1] <= yprop[`MAXOUTN];
 317                         stager[1] <= mr[`MAXOUTN];
 318                         stagei[1] <= mi[`MAXOUTN];
 319                         stagexs[1] <= xsprop[`MAXOUTN];
 320                         stageys[1] <= ysprop[`MAXOUTN];
 321                         stagers[1] <= mrs[`MAXOUTN];
 322                         stageis[1] <= mis[`MAXOUTN];
 323                         stageb[1] <= mb[`MAXOUTN];
 324                         stageci[1] <= curiter[`MAXOUTN];
 325                 end
 326         end
 327
 328         MandelUnit mu0(
 329                 mclk,
 330                 initx, inity, initxs, initys,
 331                 initr, initi, initrs, initis,
 332                 initb, initci,
 333                 xprop[0], yprop[0], xsprop[0], ysprop[0],
 334                 mr[0], mi[0], mrs[0], mis[0],
 335                 mb[0], curiter[0]);
 336
 337         MandelUnit mu1(mclk,
 338                 xprop[0], yprop[0], xsprop[0], ysprop[0], mr[0], mi[0], mrs[0], mis[0], mb[0], curiter[0],
 339                 xprop[1], yprop[1], xsprop[1], ysprop[1], mr[1], mi[1], mrs[1], mis[1], mb[1], curiter[1]);
 340         MandelUnit mu2(mclk,
 341                 xprop[1], yprop[1], xsprop[1], ysprop[1], mr[1], mi[1], mrs[1], mis[1], mb[1], curiter[1],
 342                 xprop[2], yprop[2], xsprop[2], ysprop[2], mr[2], mi[2], mrs[2], mis[2], mb[2], curiter[2]);
 343         MandelUnit mu3(mclk,
 344                 xprop[2], yprop[2], xsprop[2], ysprop[2], mr[2], mi[2], mrs[2], mis[2], mb[2], curiter[2],
 345                 xprop[3], yprop[3], xsprop[3], ysprop[3], mr[3], mi[3], mrs[3], mis[3], mb[3], curiter[3]);
 346         MandelUnit mu4(mclk,
 347                 xprop[3], yprop[3], xsprop[3], ysprop[3], mr[3], mi[3], mrs[3], mis[3], mb[3], curiter[3],
 348                 xprop[4], yprop[4], xsprop[4], ysprop[4], mr[4], mi[4], mrs[4], mis[4], mb[4], curiter[4]);
 349         MandelUnit mu5(mclk,
 350                 xprop[4], yprop[4], xsprop[4], ysprop[4], mr[4], mi[4], mrs[4], mis[4], mb[4], curiter[4],
 351                 xprop[5], yprop[5], xsprop[5], ysprop[5], mr[5], mi[5], mrs[5], mis[5], mb[5], curiter[5]);
 352         MandelUnit mu6(mclk,
 353                 xprop[5], yprop[5], xsprop[5], ysprop[5], mr[5], mi[5], mrs[5], mis[5], mb[5], curiter[5],
 354                 xprop[6], yprop[6], xsprop[6], ysprop[6], mr[6], mi[6], mrs[6], mis[6], mb[6], curiter[6]);
 355         MandelUnit mu7(mclk,
 356                 xprop[6], yprop[6], xsprop[6], ysprop[6], mr[6], mi[6], mrs[6], mis[6], mb[6], curiter[6],
 357                 xprop[7], yprop[7], xsprop[7], ysprop[7], mr[7], mi[7], mrs[7], mis[7], mb[7], curiter[7]);
 358         MandelUnit mu8(mclk,
 359                 xprop[7], yprop[7], xsprop[7], ysprop[7], mr[7], mi[7], mrs[7], mis[7], mb[7], curiter[7],
 360                 xprop[8], yprop[8], xsprop[8], ysprop[8], mr[8], mi[8], mrs[8], mis[8], mb[8], curiter[8]);
 361         MandelUnit mu9(mclk,
 362                 xprop[8], yprop[8], xsprop[8], ysprop[8], mr[8], mi[8], mrs[8], mis[8], mb[8], curiter[8],
 363                 xprop[9], yprop[9], xsprop[9], ysprop[9], mr[9], mi[9], mrs[9], mis[9], mb[9], curiter[9]);
 364         MandelUnit mua(mclk,
 365                 xprop[9],  yprop[9],  xsprop[9],  ysprop[9],  mr[9],  mi[9],  mrs[9],  mis[9],  mb[9], curiter[9],
 366                 xprop[10], yprop[10], xsprop[10], ysprop[10], mr[10], mi[10], mrs[10], mis[10], mb[10], curiter[10]);
 367         MandelUnit mub(mclk,
 368                 xprop[10], yprop[10], xsprop[10], ysprop[10], mr[10], mi[10], mrs[10], mis[10], mb[10], curiter[10],
 369                 xprop[11], yprop[11], xsprop[11], ysprop[11], mr[11], mi[11], mrs[11], mis[11], mb[11], curiter[11]);
 370
 371 endmodule
 372
 373 module Logo(
 374         input pixclk,
 375         input [11:0] x, y,
 376         output wire enb,
 377         output wire [2:0] red, green, output wire [1:0] blue);
 378
 379         reg [1:0] logo[8191:0];
 380         initial $readmemb("logo.readmemb", logo);
 381
 382         assign enb = (x < 96) && (y < 64);
 383         wire [12:0] addr = {y[5:0], x[6:0]};
 384         wire [1:0] data = logo[addr];
 385         assign {red, green, blue} =
 386                  (data == 2'b00) ? 8'b00000000 :
 387                 ((data == 2'b01) ? 8'b00011100 :
 388                 ((data == 2'b10) ? 8'b11100000 :
 389                                     8'b11111111));
 390 endmodule
 391
 392 module MandelTop(
 393         input gclk, output wire dcmok,
 394         output wire vs, hs,
 395         output wire [2:0] red, green, output [1:0] blue,
 396         input left, right, up, down, rst, cycle, logooff,
 397         input [2:0] scale);
 398
 399
 400         wire pixclk, mclk, gclk2, clk;
 401         wire dcm1ok, dcm2ok;
 402         assign dcmok = dcm1ok && dcm2ok;
 403
 404         IBUFG typeA(.O(clk), .I(gclk));
 405
 406         pixDCM dcm(                                     // CLKIN is 50MHz xtal, CLKFX_OUT is 25MHz
 407                 .CLKIN_IN(clk),
 408                 .CLKFX_OUT(pixclk),
 409                 .LOCKED_OUT(dcm1ok)
 410                 );
 411
 412         mandelDCM dcm2(
 413                 .CLKIN_IN(clk),
 414                 .CLKFX_OUT(mclk),
 415                 .LOCKED_OUT(dcm2ok)
 416                 );
 417
 418         wire border;
 419         wire [11:0] x, y;
 420         reg [13:0] xofs = -`XRES/2, yofs = -`YRES/2;
 421         reg [5:0] slowctr = 0;
 422         reg [7:0] colorcycle = 0;
 423         wire [11:0] realx, realy;
 424
 425         wire logoenb;
 426         wire [2:0] mandelr, mandelg, logor, logog;
 427         wire [1:0] mandelb, logob;
 428
 429         SyncGen sync(pixclk, vs, hs, x, y, realx, realy, border);
 430         Mandelbrot mandel(mclk, pixclk, x, y, xofs, yofs, cycle ? colorcycle : 0, scale, mandelr, mandelg, mandelb);
 431         Logo logo(pixclk, realx, realy, logoenb, logor, logog, logob);
 432
 433         assign {red,green,blue} =
 434                 border ? 8'b00000000 :
 435                 (!logooff && logoenb) ? {logor, logog, logob} : {mandelr, mandelg, mandelb};
 436
 437         always @(posedge vs)
 438         begin
 439                 if (rst)
 440                 begin
 441                         xofs <= -`XRES/2;
 442                         yofs <= -`YRES/2;
 443                         colorcycle <= 0;
 444                 end else begin
 445                         if (up) yofs <= yofs + 1;
 446                         else if (down) yofs <= yofs - 1;
 447
 448                         if (left) xofs <= xofs + 1;
 449                         else if (right) xofs <= xofs - 1;
 450
 451                         if (slowctr == 0)
 452                                 colorcycle <= colorcycle + 1;
 453                 end
 454
 455                 if (slowctr == 12)
 456                         slowctr <= 0;
 457                 else
 458                         slowctr <= slowctr + 1;
 459         end
 460 endmodule