Initial import of l2c

[snipe.git] / codegen / peephole.sml

(* L2 compiler
 * peephole optimizer
 * optimizes away redundant insns such as:
     mov a, b
     mov a, b

     mov a, b
     mov b, a

     mov a, a
     
     neg a
     neg a
 * Author: Chris Lu <czl@andrew.cmu.edu>
 *)

signature PEEPHOLE =
sig
  val peephole : x86.insn list -> x86.insn list
end

structure Peephole :> PEEPHOLE =
struct
  structure X = x86

  (* val peephole : x86.insn list -> x86.insn list *)

  fun peephole ((insn1 as X.MOVL(a1,b1))::(insn2 as X.MOVL(a2,b2))::l) =
        if(x86.opereq(a1, b1) orelse (x86.opereq(a1, a2) andalso x86.opereq(b1, b2))) then
          peephole (insn2::l)
        else if(x86.opereq(a2, b2) orelse (x86.opereq(a1, b2) andalso x86.opereq(b1, a2))) then
          peephole (insn1::l)
        else
          insn1::(peephole (insn2::l))
    | peephole ((insn as X.MOVL(a,b))::l) = if x86.opereq(a, b) then peephole l else insn::(peephole l)
    | peephole ((insn1 as X.NEG(a))::(insn2 as X.NEG(b))::l) = if x86.opereq(a, b) then peephole l else insn1::(peephole (insn2::l))
    | peephole (a::l) = a::(peephole l)
    | peephole nil = nil

end