Some LCDC IRQ stuffs. Working on fixing ldm_a

[fpgaboy.git] / LCDC.v

`define ADDR_LCDC	16'hFF40
`define ADDR_STAT	16'hFF41
`define ADDR_SCY	16'hFF42
`define ADDR_SCX	16'hFF43
`define ADDR_LY		16'hFF44
`define ADDR_LYC	16'hFF45
`define ADDR_DMA	16'hFF46
`define ADDR_BGP	16'hFF47
`define ADDR_OBP0	16'hFF48
`define ADDR_OBP1	16'hFF49
`define ADDR_WY		16'hFF4A
`define ADDR_WX		16'hFF4B

module LCDC(
	input [15:0] addr,
	inout [7:0] data,
	input clk,	// 8MHz clock
	input wr, rd,
	output wire lcdcirq,
	output wire vblankirq,
	output wire vgavs, vgahs,
	output wire [2:0] vgar, vgag, output wire [1:0] vgab);
	
	/***** Internal clock that is stable and does not depend on CPU in single/double clock mode *****/
	reg clk4 = 0;
	always @(posedge clk)
		clk4 = ~clk4;
	
	/***** LCD control registers *****/
	reg [7:0] rLCDC = 8'h91;
	reg [7:0] rSTAT = 8'h00;
	reg [7:0] rSCY = 8'b00;
	reg [7:0] rSCX = 8'b00;
	reg [7:0] rLYC = 8'b00;
	reg [7:0] rDMA = 8'b00;
	reg [7:0] rBGP = 8'b00;
	reg [7:0] rOBP0 = 8'b00;
	reg [7:0] rOBP1 = 8'b00;
	reg [7:0] rWY = 8'b00;
	reg [7:0] rWX = 8'b00;
	
	/***** Sync generation *****/
	
	/* A complete cycle takes 456 clocks.
	 * VBlank lasts 4560 clocks (10 scanlines) -- LY = 144 - 153.
	 *
	 * Modes: 0 -> in hblank and OAM/VRAM available - present 207 clks
	 *        1 -> in vblank and OAM/VRAM available
	 *        2 -> OAM in use - present 83 clks
	 *        3 -> OAM/VRAM in use - present 166 clks
	 * So, X = 0~165 is HActive,
	 * X = 166-372 is HBlank,
	 * X = 373-455 is HWhirrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrrr.
	 */
	reg [8:0] posx = 9'h000;
	reg [7:0] posy = 8'h00;
	wire [1:0] mode = (posy < 144) ?
				((posx < 166) ? 2'b11 :
				 (posx < 373) ? 2'b00 :
				 2'b10)
				: 2'b01;
	
	assign vgavs = (posy > 147) && (posy < 151);
	assign vgahs = (posx < 250) && (posx < 350);
	assign vgar = (posx < 160) && (posy < 144) ? {posy == rLYC ? 3'b111 : 3'b000} : 3'b000;
	assign vgag = (posx < 160) && (posy < 144) ? {posy < rSCY ? 3'b111 : 3'b000} : 3'b000;
	assign vgab = (posx < 160) && (posy < 144) ? {2'b11} : 2'b00;
	
	reg mode00irq = 0, mode01irq = 0, mode10irq = 0, lycirq = 0;
	assign lcdcirq = (rSTAT[3] & mode00irq) | (rSTAT[4] & mode01irq) | (rSTAT[5] & mode10irq) | (rSTAT[6] & lycirq);
	assign vblankirq = (posx == 0 && posy == 153);
	
	always @(posedge clk4)
	begin
		if (posx == 455) begin
			posx <= 0;
			if (posy == 153) begin
				posy <= 0;
				if (0 == rLYC)
					lycirq <= 1;
			end else begin
				posy <= posy + 1;
				/* Check for vblank and generate an IRQ if needed. */
				if (posy == 143) begin 
					mode01irq <= 1;
				end
				if ((posy + 1) == rLYC)
					lycirq <= 1;
				
			end
		end else begin
			posx <= posx + 1;
			if (posx == 165)
				mode00irq <= 1;
			else if (posx == 373)
				mode10irq <= 1;
			else begin
				mode00irq <= 0;
				mode01irq <= 0;
				mode10irq <= 0;
			end
			lycirq <= 0;
		end
		
	end
  
	/***** Bus interface *****/
	assign data = rd ?
			(addr == `ADDR_LCDC) ? rLCDC :
			(addr == `ADDR_STAT) ? {rSTAT[7:3], (rLYC == posy) ? 1'b1 : 1'b0, mode} :
			(addr == `ADDR_SCY) ? rSCY :
			(addr == `ADDR_SCX) ? rSCX :
			(addr == `ADDR_LY) ? posy :
			(addr == `ADDR_LYC) ? rLYC :
			(addr == `ADDR_BGP) ? rBGP :
			(addr == `ADDR_OBP0) ? rOBP0 :
			(addr == `ADDR_OBP1) ? rOBP1 :
			(addr == `ADDR_WY) ? rWY :
			(addr == `ADDR_WX) ? rWX :
			8'bzzzzzzzz :
		8'bzzzzzzzz;
  
	always @(negedge clk)
	begin
		if (wr)
			case (addr)
			`ADDR_LCDC:	rLCDC <= data;
			`ADDR_STAT:	rSTAT <= {data[7:2],rSTAT[1:0]};
			`ADDR_SCY:	rSCY <= data;
			`ADDR_SCX:	rSCX <= data;
			`ADDR_LYC:	rLYC <= data;
			`ADDR_DMA:	rDMA <= data;
			`ADDR_BGP:	rBGP <= data;
			`ADDR_OBP0:	rOBP0 <= data;
			`ADDR_OBP1:	rOBP1 <= data;
			`ADDR_WY:	rWY <= data;
			`ADDR_WX:	rWX <= data;
			endcase
	end
endmodule