[firearm.git] / Decode.v

`include "ARM_Constants.v"

module Decode(
	input clk,
	input [31:0] insn,
	input [31:0] inpc,
	input [31:0] incpsr,
	input [31:0] inspsr,
	output reg [31:0] op0,
	output reg [31:0] op1,
	output reg [31:0] op2,
	output reg carry,
	output reg [31:0] outspsr,

	output reg [3:0] read_0,
	output reg [3:0] read_1,
	output reg [3:0] read_2,
	input [31:0] rdata_0,
	input [31:0] rdata_1,
	input [31:0] rdata_2
	);

	wire [31:0] regs0, regs1, regs2;
	reg [31:0] rpc;
	reg [31:0] op0_out, op1_out, op2_out;
	reg carry_out;

	/* shifter stuff */
	wire [31:0] shift_oper;
	wire [31:0] shift_res;
	wire shift_cflag_out;
	wire [31:0] rotate_res;

	assign regs0 = (read_0 == 4'b1111) ? rpc : rdata_0;
	assign regs1 = (read_1 == 4'b1111) ? rpc : rdata_1;
	assign regs2 = rdata_2; /* use regs2 for things that cannot be r15 */

	IREALLYHATEARMSHIFT shift(.insn(insn),
	                          .operand(regs1),
	                          .reg_amt(regs2),
	                          .cflag_in(incpsr[`CPSR_C]),
	                          .res(shift_res),
	                          .cflag_out(shift_cflag_out));

	SuckLessRotator whirr(.oper({24'b0, insn[7:0]}),
	                      .amt(insn[11:8]),
	                      .res(rotate_res));

	always @(*)
		casez (insn)
		`DECODE_ALU_MULT,		/* Multiply -- must come before ALU, because it pattern matches a specific case of ALU */
//		`DECODE_ALU_MUL_LONG,		/* Multiply long */
		`DECODE_ALU_MRS,		/* MRS (Transfer PSR to register) */
		`DECODE_ALU_MSR,		/* MSR (Transfer register to PSR) */
		`DECODE_ALU_MSR_FLAGS,		/* MSR (Transfer register or immediate to PSR, flag bits only) */
		`DECODE_ALU_SWP,		/* Atomic swap */
		`DECODE_ALU_BX,			/* Branch and exchange */
		`DECODE_ALU_HDATA_REG,		/* Halfword transfer - register offset */
		`DECODE_ALU_HDATA_IMM,		/* Halfword transfer - register offset */
		`DECODE_LDRSTR_UNDEFINED,	/* Undefined. I hate ARM */
		`DECODE_LDRSTR,			/* Single data transfer */
		`DECODE_LDMSTM,			/* Block data transfer */
		`DECODE_BRANCH,			/* Branch */
		`DECODE_LDCSTC,			/* Coprocessor data transfer */
		`DECODE_CDP,			/* Coprocessor data op */
		`DECODE_SWI:			/* SWI */
			rpc = inpc + 8;
		`DECODE_MRCMCR:			/* Coprocessor register transfer */
			rpc = inpc + 12;
		`DECODE_ALU:			/* ALU */
			rpc = inpc + (insn[25] ? 8 : (insn[4] ? 12 : 8));
		default:			/* X everything else out */
			rpc = 32'hxxxxxxxx;
		endcase
	
	always @(*) begin
		read_0 = 4'hx;
		read_1 = 4'hx;
		read_2 = 4'hx;
		
		op0_out = 32'hxxxxxxxx;
		op1_out = 32'hxxxxxxxx;
		op2_out = 32'hxxxxxxxx;
		carry_out = 1'bx;
		
		casez (insn)
		`DECODE_ALU_MULT:	/* Multiply -- must come before ALU, because it pattern matches a specific case of ALU */
		begin
			read_0 = insn[15:12]; /* Rn */
			read_1 = insn[3:0];   /* Rm */
			read_2 = insn[11:8];  /* Rs */
			
			op0_out = regs0;
			op1_out = regs1;
			op2_out = regs2;
		end
//		`DECODE_ALU_MUL_LONG:	/* Multiply long */
//		begin
//			read_0 = insn[11:8]; /* Rn */
//			read_1 = insn[3:0];   /* Rm */
//			read_2 = 4'b0;       /* anyus */
//
//			op1_res = regs1;
//		end
		`DECODE_ALU_MRS:	/* MRS (Transfer PSR to register) */
		begin end
		`DECODE_ALU_MSR:	/* MSR (Transfer register to PSR) */
		begin
			read_0 = insn[3:0];	/* Rm */
			
			op0_out = regs0;
		end
		`DECODE_ALU_MSR_FLAGS:	/* MSR (Transfer register or immediate to PSR, flag bits only) */
		begin
			read_0 = insn[3:0];	/* Rm */
			
			if(insn[25]) begin     /* the constant case */
				op0_out = rotate_res;
			end else begin
				op0_out = regs0;
			end
		end
		`DECODE_ALU_SWP:	/* Atomic swap */
		begin
			read_0 = insn[19:16]; /* Rn */
			read_1 = insn[3:0];   /* Rm */
			
			op0_out = regs0;
			op1_out = regs1;
		end
		`DECODE_ALU_BX:		/* Branch and exchange */
		begin
			read_0 = insn[3:0];   /* Rn */
			
			op0_out = regs0;
		end
		`DECODE_ALU_HDATA_REG:	/* Halfword transfer - register offset */
		begin
			read_0 = insn[19:16];
			read_1 = insn[3:0];
			read_2 = insn[15:12];

			op0_out = regs0;
			op1_out = regs1;
			op2_out = regs2;
		end
		`DECODE_ALU_HDATA_IMM:	/* Halfword transfer - immediate offset */
		begin
			read_0 = insn[19:16];
			read_1 = insn[15:12];
			
			op0_out = regs0;
			op1_out = {24'b0, insn[11:8], insn[3:0]};
			op2_out = regs1;
		end
		`DECODE_ALU:		/* ALU */
		begin
			read_0 = insn[19:16]; /* Rn */
			read_1 = insn[3:0];   /* Rm */
			read_2 = insn[11:8];  /* Rs for shift */
			
			op0_out = regs0;
			if(insn[25]) begin     /* the constant case */
				carry_out = incpsr[`CPSR_C];
				op1_out = rotate_res;
			end else begin
				carry_out = shift_cflag_out;
				op1_out = shift_res;
			end
		end
		`DECODE_LDRSTR_UNDEFINED:	/* Undefined. I hate ARM */
		begin
			/* eat shit */
		end
		`DECODE_LDRSTR:		/* Single data transfer */
		begin
			read_0 = insn[19:16]; /* Rn */
			read_1 = insn[3:0];   /* Rm */
			read_2 = insn[15:12];
			
			op0_out = regs0;
			if(insn[25]) begin
				op1_out = {20'b0, insn[11:0]};
				carry_out = incpsr[`CPSR_C];
			end else begin
				op1_out = shift_res;
				carry_out = shift_cflag_out;
			end
			op2_out = regs2;
		end
		`DECODE_LDMSTM:		/* Block data transfer */
		begin
			read_0 = insn[19:16];
			
			op0_out = regs0;
			op1_out = {16'b0, insn[15:0]};
		end
		`DECODE_BRANCH:		/* Branch */
		begin
			op0_out = {{6{insn[23]}}, insn[23:0], 2'b0};
		end
		`DECODE_LDCSTC:		/* Coprocessor data transfer */
		begin
			read_0 = insn[19:16];
			
			op0_out = regs0;
			op1_out = {24'b0, insn[7:0]};
		end
		`DECODE_CDP:		/* Coprocessor data op */
		begin
		end
		`DECODE_MRCMCR:		/* Coprocessor register transfer */
		begin
			read_0 = insn[15:12];
			
			op0_out = regs0;
		end
		`DECODE_SWI:		/* SWI */
		begin
		end
		default:
			$display("Undecoded instruction");
		endcase
	end

	
	always @ (posedge clk) begin
		op0 <= op0_out;   /* Rn - always */
		op1 <= op1_out; /* 'operand 2' - Rm */
		op2 <= op2_out;   /* thirdedge - Rs */
		carry <= carry_out;
		outspsr <= inspsr;
	end

endmodule

module IREALLYHATEARMSHIFT(
	input [31:0] insn,
	input [31:0] operand,
	input [31:0] reg_amt,
	input cflag_in,
	output reg [31:0] res,
	output reg cflag_out
);
	wire [5:0] shift_amt;
	reg is_arith, is_rot;
	wire rshift_cout;
	wire [31:0] rshift_res;

	assign shift_amt = insn[4] ? {|reg_amt[7:5], reg_amt[4:0]}     /* reg-specified shift */
	                           : {insn[11:7] == 5'b0, insn[11:7]}; /* immediate shift */

	SuckLessShifter barrel(.oper(operand),
	                       .carryin(cflag_in),
	                       .amt(shift_amt),
	                       .is_arith(is_arith),
	                       .is_rot(is_rot),
	                       .res(rshift_res),
	                       .carryout(rshift_cout));

	always @(*)
		case (insn[6:5])
		`SHIFT_LSL: begin
			/* meaningless */
			is_rot = 1'b0;
			is_arith = 1'b0;
		end
		`SHIFT_LSR: begin
			is_rot = 1'b0;
			is_arith = 1'b0;
		end
		`SHIFT_ASR: begin
			is_rot = 1'b0;
			is_arith = 1'b1;
		end
		`SHIFT_ROR: begin
			is_rot = 1'b1;
			is_arith = 1'b0;
		end
		endcase

	always @(*)
		case (insn[6:5]) /* shift type */
		`SHIFT_LSL:
			{cflag_out, res} = {cflag_in, operand} << {insn[4] & shift_amt[5], shift_amt[4:0]};
		`SHIFT_LSR: begin
			res = rshift_res;
			cflag_out = rshift_cout;
		end
		`SHIFT_ASR: begin
			res = rshift_res;
			cflag_out = rshift_cout;
		end
		`SHIFT_ROR: begin
			if(!insn[4] && shift_amt[4:0] == 5'b0) begin /* RRX x.x */
				res = {cflag_in, operand[31:1]};
				cflag_out = operand[0];
			end else begin
				res = rshift_res;
				cflag_out = rshift_cout;
			end
		end
		endcase
endmodule

module SuckLessShifter(
	input [31:0] oper,
	input carryin,
	input [5:0] amt,
	input is_arith,
	input is_rot,
	output wire [31:0] res,
	output wire carryout
);

	wire [32:0] stage1, stage2, stage3, stage4, stage5;

	wire pushbits = is_arith & oper[31];

	/* do a barrel shift */
	assign stage1 = amt[5] ? {is_rot ? oper : {32{pushbits}}, oper[31]} : {oper, carryin};
	assign stage2 = amt[4] ? {is_rot ? stage1[16:1] : {16{pushbits}}, stage1[32:17], stage1[16]} : stage1;
	assign stage3 = amt[3] ? {is_rot ? stage2[8:1] : {8{pushbits}}, stage2[32:9], stage2[8]} : stage2;
	assign stage4 = amt[2] ? {is_rot ? stage3[4:1] : {4{pushbits}}, stage3[32:5], stage3[4]} : stage3;
	assign stage5 = amt[1] ? {is_rot ? stage4[2:1] : {2{pushbits}}, stage4[32:3], stage4[2]} : stage4;
	assign {res, carryout} = amt[0] ? {is_rot ? stage5[1] : pushbits, stage5[32:2], stage5[1]} : stage5;

endmodule

module SuckLessRotator(
	input [31:0] oper,
	input [3:0] amt,
	output wire [31:0] res
);

	wire [31:0] stage1, stage2, stage3;
	assign stage1 = amt[3] ? {oper[15:0], oper[31:16]} : oper;
	assign stage2 = amt[2] ? {stage1[7:0], stage1[31:8]} : stage1;
	assign stage3 = amt[1] ? {stage2[3:0], stage2[31:4]} : stage2;
	assign res    = amt[0] ? {stage3[1:0], stage3[31:2]} : stage3;

endmodule
Commit	Line	Data
26049339 CL	1	`include "ARM_Constants.v"
26049339 CL	2
bae77231 CL	3	module Decode(
bae77231 CL	4	input clk,
be64a9df	5	input [31:0] insn,
bae77231	6	input [31:0] inpc,
821617bb	7	input [31:0] incpsr,
cb0428b6	8	input [31:0] inspsr,
bae77231 CL	9	output reg [31:0] op0,
	10	output reg [31:0] op1,
	11	output reg [31:0] op2,
42c1e610	12	output reg carry,
cb0428b6	13	output reg [31:0] outspsr,
bae77231	14
fbe84cc1 JW	15	output reg [3:0] read_0,
	16	output reg [3:0] read_1,
	17	output reg [3:0] read_2,
821617bb JW	18	input [31:0] rdata_0,
	19	input [31:0] rdata_1,
	20	input [31:0] rdata_2
bae77231 CL	21	);
bae77231 CL	22
fbe84cc1 JW	23	wire [31:0] regs0, regs1, regs2;
	24	reg [31:0] rpc;
	25	reg [31:0] op0_out, op1_out, op2_out;
	26	reg carry_out;
bae77231 CL	27
	28	/* shifter stuff */
	29	wire [31:0] shift_oper;
	30	wire [31:0] shift_res;
	31	wire shift_cflag_out;
a0c8a75c	32	wire [31:0] rotate_res;
bae77231	33
821617bb JW	34	assign regs0 = (read_0 == 4'b1111) ? rpc : rdata_0;
	35	assign regs1 = (read_1 == 4'b1111) ? rpc : rdata_1;
	36	assign regs2 = rdata_2; /* use regs2 for things that cannot be r15 */
bae77231	37
96f7e6e1 JW	38	IREALLYHATEARMSHIFT shift(.insn(insn),
	39	.operand(regs1),
	40	.reg_amt(regs2),
	41	.cflag_in(incpsr[`CPSR_C]),
	42	.res(shift_res),
	43	.cflag_out(shift_cflag_out));
e2c5d224	44
a0c8a75c CL	45	SuckLessRotator whirr(.oper({24'b0, insn[7:0]}),
	46	.amt(insn[11:8]),
	47	.res(rotate_res));
	48
be64a9df JW	49	always @(*)
be64a9df JW	50	casez (insn)
2c523f8a JW	51	`DECODE_ALU_MULT, /* Multiply -- must come before ALU, because it pattern matches a specific case of ALU */
	52	// `DECODE_ALU_MUL_LONG, /* Multiply long */
	53	`DECODE_ALU_MRS, /* MRS (Transfer PSR to register) */
	54	`DECODE_ALU_MSR, /* MSR (Transfer register to PSR) */
	55	`DECODE_ALU_MSR_FLAGS, /* MSR (Transfer register or immediate to PSR, flag bits only) */
	56	`DECODE_ALU_SWP, /* Atomic swap */
	57	`DECODE_ALU_BX, /* Branch and exchange */
	58	`DECODE_ALU_HDATA_REG, /* Halfword transfer - register offset */
	59	`DECODE_ALU_HDATA_IMM, /* Halfword transfer - register offset */
	60	`DECODE_LDRSTR_UNDEFINED, /* Undefined. I hate ARM */
	61	`DECODE_LDRSTR, /* Single data transfer */
	62	`DECODE_LDMSTM, /* Block data transfer */
	63	`DECODE_BRANCH, /* Branch */
	64	`DECODE_LDCSTC, /* Coprocessor data transfer */
	65	`DECODE_CDP, /* Coprocessor data op */
2c523f8a	66	`DECODE_SWI: /* SWI */
b3bb2fb8	67	rpc = inpc + 8;
04d95cf5 JW	68	`DECODE_MRCMCR: /* Coprocessor register transfer */
04d95cf5 JW	69	rpc = inpc + 12;
2c523f8a	70	`DECODE_ALU: /* ALU */
b3bb2fb8	71	rpc = inpc + (insn[25] ? 8 : (insn[4] ? 12 : 8));
2c523f8a	72	default: /* X everything else out */
be64a9df JW	73	rpc = 32'hxxxxxxxx;
be64a9df JW	74	endcase
96f7e6e1	75
326fd4c3 JW	76	always @(*) begin
	77	read_0 = 4'hx;
	78	read_1 = 4'hx;
	79	read_2 = 4'hx;
	80
96f7e6e1 JW	81	op0_out = 32'hxxxxxxxx;
	82	op1_out = 32'hxxxxxxxx;
	83	op2_out = 32'hxxxxxxxx;
	84	carry_out = 1'bx;
	85
0bc7ede9	86	casez (insn)
2c523f8a	87	`DECODE_ALU_MULT: /* Multiply -- must come before ALU, because it pattern matches a specific case of ALU */
326fd4c3	88	begin
0bc7ede9	89	read_0 = insn[15:12]; /* Rn */
326fd4c3 JW	90	read_1 = insn[3:0]; /* Rm */
326fd4c3 JW	91	read_2 = insn[11:8]; /* Rs */
96f7e6e1 JW	92
	93	op0_out = regs0;
	94	op1_out = regs1;
	95	op2_out = regs2;
326fd4c3	96	end
2c523f8a	97	// `DECODE_ALU_MUL_LONG: /* Multiply long */
96f7e6e1	98	// begin
0bc7ede9	99	// read_0 = insn[11:8]; /* Rn */
326fd4c3 JW	100	// read_1 = insn[3:0]; /* Rm */
326fd4c3 JW	101	// read_2 = 4'b0; /* anyus */
96f7e6e1 JW	102	//
	103	// op1_res = regs1;
	104	// end
2c523f8a	105	`DECODE_ALU_MRS: /* MRS (Transfer PSR to register) */
42c1e610	106	begin end
96f7e6e1 JW	107	`DECODE_ALU_MSR: /* MSR (Transfer register to PSR) */
	108	begin
	109	read_0 = insn[3:0]; /* Rm */
	110
	111	op0_out = regs0;
	112	end
2c523f8a	113	`DECODE_ALU_MSR_FLAGS: /* MSR (Transfer register or immediate to PSR, flag bits only) */
96f7e6e1	114	begin
42c1e610	115	read_0 = insn[3:0]; /* Rm */
96f7e6e1 JW	116
	117	if(insn[25]) begin /* the constant case */
	118	op0_out = rotate_res;
	119	end else begin
	120	op0_out = regs0;
	121	end
	122	end
2c523f8a	123	`DECODE_ALU_SWP: /* Atomic swap */
326fd4c3	124	begin
0bc7ede9	125	read_0 = insn[19:16]; /* Rn */
326fd4c3	126	read_1 = insn[3:0]; /* Rm */
96f7e6e1 JW	127
	128	op0_out = regs0;
	129	op1_out = regs1;
326fd4c3	130	end
2c523f8a	131	`DECODE_ALU_BX: /* Branch and exchange */
96f7e6e1	132	begin
0bc7ede9	133	read_0 = insn[3:0]; /* Rn */
96f7e6e1 JW	134
	135	op0_out = regs0;
	136	end
2c523f8a	137	`DECODE_ALU_HDATA_REG: /* Halfword transfer - register offset */
326fd4c3	138	begin
0bc7ede9	139	read_0 = insn[19:16];
326fd4c3	140	read_1 = insn[3:0];
778ef14f CL	141	read_2 = insn[15:12];
778ef14f CL	142
96f7e6e1 JW	143	op0_out = regs0;
96f7e6e1 JW	144	op1_out = regs1;
778ef14f	145	op2_out = regs2;
326fd4c3	146	end
2c523f8a	147	`DECODE_ALU_HDATA_IMM: /* Halfword transfer - immediate offset */
326fd4c3	148	begin
0bc7ede9	149	read_0 = insn[19:16];
778ef14f	150	read_1 = insn[15:12];
96f7e6e1 JW	151
	152	op0_out = regs0;
	153	op1_out = {24'b0, insn[11:8], insn[3:0]};
778ef14f	154	op2_out = regs1;
326fd4c3	155	end
2c523f8a JW	156	`DECODE_ALU: /* ALU */
	157	begin
	158	read_0 = insn[19:16]; /* Rn */
	159	read_1 = insn[3:0]; /* Rm */
	160	read_2 = insn[11:8]; /* Rs for shift */
96f7e6e1	161
2c523f8a JW	162	op0_out = regs0;
	163	if(insn[25]) begin /* the constant case */
	164	carry_out = incpsr[`CPSR_C];
	165	op1_out = rotate_res;
	166	end else begin
	167	carry_out = shift_cflag_out;
	168	op1_out = shift_res;
	169	end
	170	end
96f7e6e1 JW	171	`DECODE_LDRSTR_UNDEFINED: /* Undefined. I hate ARM */
96f7e6e1 JW	172	begin
bae77231 CL	173	/* eat shit */
bae77231 CL	174	end
96f7e6e1 JW	175	`DECODE_LDRSTR: /* Single data transfer */
	176	begin
	177	read_0 = insn[19:16]; /* Rn */
	178	read_1 = insn[3:0]; /* Rm */
6d0f9d82	179	read_2 = insn[15:12];
96f7e6e1	180
42c1e610	181	op0_out = regs0;
be64a9df	182	if(insn[25]) begin
42c1e610 JW	183	op1_out = {20'b0, insn[11:0]};
42c1e610 JW	184	carry_out = incpsr[`CPSR_C];
bae77231	185	end else begin
42c1e610 JW	186	op1_out = shift_res;
42c1e610 JW	187	carry_out = shift_cflag_out;
bae77231	188	end
6d0f9d82	189	op2_out = regs2;
bae77231	190	end
96f7e6e1 JW	191	`DECODE_LDMSTM: /* Block data transfer */
	192	begin
	193	read_0 = insn[19:16];
	194
42c1e610 JW	195	op0_out = regs0;
42c1e610 JW	196	op1_out = {16'b0, insn[15:0]};
bae77231	197	end
96f7e6e1 JW	198	`DECODE_BRANCH: /* Branch */
96f7e6e1 JW	199	begin
42c1e610	200	op0_out = {{6{insn[23]}}, insn[23:0], 2'b0};
bae77231	201	end
96f7e6e1 JW	202	`DECODE_LDCSTC: /* Coprocessor data transfer */
	203	begin
	204	read_0 = insn[19:16];
	205
42c1e610 JW	206	op0_out = regs0;
42c1e610 JW	207	op1_out = {24'b0, insn[7:0]};
bae77231	208	end
96f7e6e1 JW	209	`DECODE_CDP: /* Coprocessor data op */
96f7e6e1 JW	210	begin
bae77231	211	end
96f7e6e1 JW	212	`DECODE_MRCMCR: /* Coprocessor register transfer */
	213	begin
	214	read_0 = insn[15:12];
	215
42c1e610	216	op0_out = regs0;
bae77231	217	end
96f7e6e1 JW	218	`DECODE_SWI: /* SWI */
96f7e6e1 JW	219	begin
bae77231	220	end
96f7e6e1 JW	221	default:
96f7e6e1 JW	222	$display("Undecoded instruction");
bae77231 CL	223	endcase
	224	end
	225
96f7e6e1	226
bae77231	227	always @ (posedge clk) begin
42c1e610 JW	228	op0 <= op0_out; /* Rn - always */
	229	op1 <= op1_out; /* 'operand 2' - Rm */
	230	op2 <= op2_out; /* thirdedge - Rs */
	231	carry <= carry_out;
cb0428b6	232	outspsr <= inspsr;
bae77231 CL	233	end
	234
	235	endmodule
	236
e2c5d224	237	module IREALLYHATEARMSHIFT(
bae77231 CL	238	input [31:0] insn,
	239	input [31:0] operand,
	240	input [31:0] reg_amt,
	241	input cflag_in,
fbe84cc1 JW	242	output reg [31:0] res,
fbe84cc1 JW	243	output reg cflag_out
bae77231	244	);
bae77231	245	wire [5:0] shift_amt;
f61f8d6f JW	246	reg is_arith, is_rot;
	247	wire rshift_cout;
	248	wire [31:0] rshift_res;
e2c5d224 CL	249
	250	assign shift_amt = insn[4] ? {\|reg_amt[7:5], reg_amt[4:0]} /* reg-specified shift */
	251	: {insn[11:7] == 5'b0, insn[11:7]}; /* immediate shift */
bae77231	252
96f7e6e1	253	SuckLessShifter barrel(.oper(operand),
e2c5d224 CL	254	.carryin(cflag_in),
	255	.amt(shift_amt),
	256	.is_arith(is_arith),
	257	.is_rot(is_rot),
	258	.res(rshift_res),
	259	.carryout(rshift_cout));
bae77231	260
821617bb	261	always @(*)
e2c5d224 CL	262	case (insn[6:5])
e2c5d224 CL	263	`SHIFT_LSL: begin
e5fb7d86	264	/* meaningless */
e2c5d224 CL	265	is_rot = 1'b0;
e2c5d224 CL	266	is_arith = 1'b0;
26049339	267	end
e2c5d224 CL	268	`SHIFT_LSR: begin
	269	is_rot = 1'b0;
	270	is_arith = 1'b0;
	271	end
	272	`SHIFT_ASR: begin
	273	is_rot = 1'b0;
	274	is_arith = 1'b1;
	275	end
	276	`SHIFT_ROR: begin
	277	is_rot = 1'b1;
	278	is_arith = 1'b0;
	279	end
	280	endcase
	281
821617bb	282	always @(*)
26049339	283	case (insn[6:5]) /* shift type */
e2c5d224 CL	284	`SHIFT_LSL:
e2c5d224 CL	285	{cflag_out, res} = {cflag_in, operand} << {insn[4] & shift_amt[5], shift_amt[4:0]};
bae77231	286	`SHIFT_LSR: begin
e2c5d224 CL	287	res = rshift_res;
e2c5d224 CL	288	cflag_out = rshift_cout;
bae77231 CL	289	end
bae77231 CL	290	`SHIFT_ASR: begin
e2c5d224 CL	291	res = rshift_res;
e2c5d224 CL	292	cflag_out = rshift_cout;
bae77231 CL	293	end
bae77231 CL	294	`SHIFT_ROR: begin
e2c5d224	295	if(!insn[4] && shift_amt[4:0] == 5'b0) begin /* RRX x.x */
bae77231 CL	296	res = {cflag_in, operand[31:1]};
bae77231 CL	297	cflag_out = operand[0];
e5fb7d86	298	end else begin
e2c5d224 CL	299	res = rshift_res;
e2c5d224 CL	300	cflag_out = rshift_cout;
bae77231 CL	301	end
bae77231 CL	302	end
26049339	303	endcase
bae77231	304	endmodule
e2c5d224 CL	305
	306	module SuckLessShifter(
	307	input [31:0] oper,
	308	input carryin,
	309	input [5:0] amt,
	310	input is_arith,
	311	input is_rot,
f61f8d6f JW	312	output wire [31:0] res,
f61f8d6f JW	313	output wire carryout
e2c5d224 CL	314	);
	315
	316	wire [32:0] stage1, stage2, stage3, stage4, stage5;
	317
e5fb7d86	318	wire pushbits = is_arith & oper[31];
e2c5d224 CL	319
	320	/* do a barrel shift */
	321	assign stage1 = amt[5] ? {is_rot ? oper : {32{pushbits}}, oper[31]} : {oper, carryin};
6c715b10 CL	322	assign stage2 = amt[4] ? {is_rot ? stage1[16:1] : {16{pushbits}}, stage1[32:17], stage1[16]} : stage1;
	323	assign stage3 = amt[3] ? {is_rot ? stage2[8:1] : {8{pushbits}}, stage2[32:9], stage2[8]} : stage2;
	324	assign stage4 = amt[2] ? {is_rot ? stage3[4:1] : {4{pushbits}}, stage3[32:5], stage3[4]} : stage3;
	325	assign stage5 = amt[1] ? {is_rot ? stage4[2:1] : {2{pushbits}}, stage4[32:3], stage4[2]} : stage4;
	326	assign {res, carryout} = amt[0] ? {is_rot ? stage5[1] : pushbits, stage5[32:2], stage5[1]} : stage5;
e2c5d224 CL	327
e2c5d224 CL	328	endmodule
a0c8a75c CL	329
	330	module SuckLessRotator(
	331	input [31:0] oper,
	332	input [3:0] amt,
f61f8d6f	333	output wire [31:0] res
a0c8a75c CL	334	);
	335
	336	wire [31:0] stage1, stage2, stage3;
	337	assign stage1 = amt[3] ? {oper[15:0], oper[31:16]} : oper;
	338	assign stage2 = amt[2] ? {stage1[7:0], stage1[31:8]} : stage1;
	339	assign stage3 = amt[1] ? {stage2[3:0], stage2[31:4]} : stage2;
	340	assign res = amt[0] ? {stage3[1:0], stage3[31:2]} : stage3;
	341
	342	endmodule
96f7e6e1	343